【VBA】全シートを一括で保護または保護解除するサンプルコード

Sub 全シート保護_簡易版()
'保護(VBAからの変更は許可)

    Dim WS As Worksheet
    For Each WS In Worksheets
        WS.Protect Password:="1234", UserInterfaceOnly:=True
    Next WS

End Sub

Sub 全シート保護解除_簡易版()

    Dim WS As Worksheet
    For Each WS In Worksheets
        WS.Unprotect Password:="1234"
    Next WS
     
End Sub

Sub 全シート保護_通常版()

    'パスワード指定
    Dim PassWD As String
    PassWD = "1234"
    
    '画面更新／イベントを停止
    Application.ScreenUpdating = False
    Application.EnableEvents = False
     
    'ブック保護解除
    ThisWorkbook.Unprotect Password:=PassWD
   
    '保護(VBAからの変更は許可)
    Dim WS As Worksheet
    For Each WS In Worksheets
        WS.Protect Password:=PassWD, UserInterfaceOnly:=True
    Next WS

    'ブック再保護
    ThisWorkbook.Protect Password:=PassWD

    '画面更新／イベントを再開
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

Sub 全シート保護解除_通常版()

    'パスワード指定
    Dim PassWD As String
    PassWD = "1234"
    
    '画面更新／イベントを停止
    Application.ScreenUpdating = False
    Application.EnableEvents = False
     
    'ブック保護解除
    ThisWorkbook.Unprotect Password:=PassWD
    
    '保護解除
    Dim WS As Worksheet
    For Each WS In Worksheets
        WS.Unprotect Password:=PassWD
    Next WS
     
    '(ブック再保護をする場合はコメントアウトを外す)
    'ThisWorkbook.Protect Password:=PassWD
    
    '画面更新／イベントを再開
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

Sub 全シート保護_実用版()

    'パスワード指定
    Dim PassWD As String
    PassWD = "1234"
    
    '画面更新／イベントを停止
    Application.ScreenUpdating = False
    Application.EnableEvents = False
         
    'ブック保護解除
    ThisWorkbook.Unprotect Password:=PassWD
   
    '非表示シート再表示(全シートに表示処理をするため一旦再表示)
    On Error Resume Next '非表示シートがないときに出るエラー無視
    Dim WS As Worksheet
    For Each WS In Worksheets
        WS.Visible = True
    Next WS
    
    '切替処理
    For Each WS In Worksheets
    
        '保護(VBAからの変更は許可)
        WS.Protect Password:=PassWD, UserInterfaceOnly:=True
        
        'セル選択設定(必要に応じてどちらかのコメントを外す)
        'WS.EnableSelection = xlUnlockedCells 'ロックされていないセルのみ選択可
        WS.EnableSelection = xlNoRestrictions 'ロックされたセルも選択可
     
        '枠線表示・行列番号非表示のためのシート選択
        WS.Activate
        
        '枠線非表示(表示：True，非表示：False)
        ActiveWindow.DisplayGridlines = False
        
        '行列番号非表示(表示：True，非表示：False)
        ActiveWindow.DisplayHeadings = False
        
    Next WS
    
    '一部シートを非表示にする場合に記載
    Sheet2.Visible = False
    Sheet4.Visible = False
         
    'TOPシートに戻る
    Sheet1.Activate
        
    'ブック再保護
    ThisWorkbook.Protect Password:=PassWD

    '画面更新／イベントを再開
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

Sub 全シート保護解除_実用版()

    'パスワード指定
    Dim PassWD As String
    PassWD = "1234"
    
    '画面更新／イベントを停止
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    
    'ブック保護解除
    ThisWorkbook.Unprotect Password:=PassWD
    
    '非表示シート再表示(全シートに表示処理をするため一旦再表示)
    On Error Resume Next '非表示シートがないときに出るエラー無視
    Dim WS As Worksheet
    For Each WS In Worksheets
        WS.Visible = True
    Next WS
        
    '切替処理
    For Each WS In Worksheets
    
        '保護解除
        WS.Unprotect Password:=PassWD
        
        '枠線表示・行列番号表示のためのシート選択
        WS.Activate
        
        '枠線表示(表示：True，非表示：False)
        ActiveWindow.DisplayGridlines = True
    
        '行列番号表示(表示：True，非表示：False)
        ActiveWindow.DisplayHeadings = True
    
    Next WS
     
    'TOPシートに戻る
    Sheet1.Activate
        
    '(ブック再保護をする場合はコメントアウトを外す)
    'ThisWorkbook.Protect Password:=PassWD
    
    '画面更新／イベントを再開
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub